mirror of
https://github.com/zeek/zeek.git
synced 2025-10-03 07:08:19 +00:00
d8b05af7e5
Closes #1002. * origin/topic/jsiwek/faf-cleanup: Move file analyzers to new plugin infrastructure. Add a general file analysis overview/how-to document. Improve file analysis doxygen comments. Improve tracking of HTTP file extraction (addresses #988). Fix HTTP multipart body file analysis. Remove logging of analyzers field of FileAnalysis::Info. Remove extraction counter in default file extraction scripts. Remove FileAnalysis::postpone_timeout. Make default get_file_handle handlers &priority=5. Add input interface to forward data for file analysis. File analysis framework interface simplifications.
54 lines
1.4 KiB
Text
54 lines
1.4 KiB
Text
@load ./main
|
|
@load ./utils
|
|
@load base/utils/conn-ids
|
|
@load base/frameworks/file-analysis/main
|
|
|
|
module HTTP;
|
|
|
|
export {
|
|
redef record HTTP::Info += {
|
|
## Number of MIME entities in the HTTP request message body so far.
|
|
request_mime_level: count &default=0;
|
|
## Number of MIME entities in the HTTP response message body so far.
|
|
response_mime_level: count &default=0;
|
|
};
|
|
|
|
## Default file handle provider for HTTP.
|
|
global get_file_handle: function(c: connection, is_orig: bool): string;
|
|
}
|
|
|
|
event http_begin_entity(c: connection, is_orig: bool) &priority=5
|
|
{
|
|
if ( ! c?$http )
|
|
return;
|
|
|
|
if ( is_orig )
|
|
++c$http$request_mime_level;
|
|
else
|
|
++c$http$response_mime_level;
|
|
}
|
|
|
|
function get_file_handle(c: connection, is_orig: bool): string
|
|
{
|
|
if ( ! c?$http ) return "";
|
|
|
|
local mime_level: count =
|
|
is_orig ? c$http$request_mime_level : c$http$response_mime_level;
|
|
local mime_level_str: string = mime_level > 1 ? cat(mime_level) : "";
|
|
|
|
if ( c$http$range_request )
|
|
return cat(Analyzer::ANALYZER_HTTP, " ", is_orig, " ", c$id$orig_h, " ",
|
|
build_url(c$http));
|
|
|
|
return cat(Analyzer::ANALYZER_HTTP, " ", c$start_time, " ", is_orig, " ",
|
|
c$http$trans_depth, mime_level_str, " ", id_string(c$id));
|
|
}
|
|
|
|
module GLOBAL;
|
|
|
|
event get_file_handle(tag: Analyzer::Tag, c: connection, is_orig: bool)
|
|
&priority=5
|
|
{
|
|
if ( tag != Analyzer::ANALYZER_HTTP ) return;
|
|
set_file_handle(HTTP::get_file_handle(c, is_orig));
|
|
}
|