mirror of
https://github.com/zeek/zeek.git
synced 2025-10-14 04:28:20 +00:00
26ff8e1dab
* origin/topic/seth/notice-email-delay: The hostname notice email extension works now. Fixed more bugs with delayed emails. Working around a problem with setting default container types. Ugh, still major failure. I'm just cutting the timeout handling for now. Fixed a small bug major problem with email delay timeout catching. Initial fixes for the problem of async actions with notice email extensions. Closes #727.
47 lines
1.6 KiB
Text
47 lines
1.6 KiB
Text
@load ../main
|
|
|
|
module Notice;
|
|
|
|
# We have to store references to the notices here because the when statement
|
|
# clones the frame which doesn't give us access to modify values outside
|
|
# of it's execution scope. (we get a clone of the notice instead of a
|
|
# reference to the original notice)
|
|
global tmp_notice_storage: table[string] of Notice::Info &create_expire=max_email_delay+10secs;
|
|
|
|
event Notice::notice(n: Notice::Info) &priority=10
|
|
{
|
|
if ( ! n?$src && ! n?$dst )
|
|
return;
|
|
|
|
# This should only be done for notices that are being sent to email.
|
|
if ( ACTION_EMAIL !in n$actions )
|
|
return;
|
|
|
|
# I'm not recovering gracefully from the when statements because I want
|
|
# the notice framework to detect that something has exceeded the maximum
|
|
# allowed email delay and tell the user.
|
|
local uid = unique_id("");
|
|
tmp_notice_storage[uid] = n;
|
|
|
|
local output = "";
|
|
if ( n?$src )
|
|
{
|
|
add n$email_delay_tokens["hostnames-src"];
|
|
when ( local src_name = lookup_addr(n$src) )
|
|
{
|
|
output = string_cat("orig/src hostname: ", src_name, "\n");
|
|
tmp_notice_storage[uid]$email_body_sections[|tmp_notice_storage[uid]$email_body_sections|] = output;
|
|
delete tmp_notice_storage[uid]$email_delay_tokens["hostnames-src"];
|
|
}
|
|
}
|
|
if ( n?$dst )
|
|
{
|
|
add n$email_delay_tokens["hostnames-dst"];
|
|
when ( local dst_name = lookup_addr(n$dst) )
|
|
{
|
|
output = string_cat("resp/dst hostname: ", dst_name, "\n");
|
|
tmp_notice_storage[uid]$email_body_sections[|tmp_notice_storage[uid]$email_body_sections|] = output;
|
|
delete tmp_notice_storage[uid]$email_delay_tokens["hostnames-dst"];
|
|
}
|
|
}
|
|
}
|