mirror of
https://github.com/zeek/zeek.git
synced 2025-10-08 01:28:20 +00:00
54aaf3a623
- This gives the cluster controller and agent the common name "Management framework" and changes the start directory of the sources from "policy/frameworks/cluster" to "policy/frameworks/management". This avoids ambiguity with the existing cluster framework. - It renames the "ClusterController" and "ClusterAgent" script modules to "Management::Controller" and "Management::Agent", respectively. This allows us to anchor tooling common to both controller and agent at the "Management" module. - It moves common configuration settings, logging, requests, types, and utilities to the common "Management" module. - It removes the explicit "::Types" submodule (so a request/response result is now a Management::Result, not a Management::Types::Result), which makes typenames more readable. - It updates tests that depend on module naming and full set of scripts.
41 lines
1.4 KiB
Text
41 lines
1.4 KiB
Text
##! The cluster agent boot logic runs in Zeek's supervisor and instructs it to
|
|
##! launch a Management agent process. The agent's main logic resides in main.zeek,
|
|
##! similarly to other frameworks. The new process will execute that script.
|
|
##!
|
|
##! If the current process is not the Zeek supervisor, this does nothing.
|
|
|
|
@load ./config
|
|
|
|
# The agent needs the supervisor to listen for node management requests. We
|
|
# need to tell it to do so, and we need to do so here, in the agent
|
|
# bootstrapping code, so the redef applies prior to the fork of the agent
|
|
# process itself.
|
|
redef SupervisorControl::enable_listen = T;
|
|
|
|
event zeek_init()
|
|
{
|
|
if ( ! Supervisor::is_supervisor() )
|
|
return;
|
|
|
|
local epi = Management::Agent::endpoint_info();
|
|
local sn = Supervisor::NodeConfig($name=epi$id, $bare_mode=T,
|
|
$scripts=vector("policy/frameworks/management/agent/main.zeek"));
|
|
|
|
if ( Management::Agent::directory != "" )
|
|
sn$directory = Management::Agent::directory;
|
|
if ( Management::Agent::stdout_file_suffix != "" )
|
|
sn$stdout_file = epi$id + "." + Management::Agent::stdout_file_suffix;
|
|
if ( Management::Agent::stderr_file_suffix != "" )
|
|
sn$stderr_file = epi$id + "." + Management::Agent::stderr_file_suffix;
|
|
|
|
# This helps Zeek run controller and agent with a minimal set of scripts.
|
|
sn$env["ZEEK_CLUSTER_MGMT_NODE"] = "AGENT";
|
|
|
|
local res = Supervisor::create(sn);
|
|
|
|
if ( res != "" )
|
|
{
|
|
print(fmt("error: supervisor could not create agent node: %s", res));
|
|
exit(1);
|
|
}
|
|
}
|