mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 14:48:21 +00:00
1bd658da8f
This adds a "policy" hook into the logging framework's streams and
filters to replace the existing log filter predicates. The hook
signature is as follows:
hook(rec: any, id: Log::ID, filter: Log::Filter);
The logging manager invokes hooks on each log record. Hooks can veto
log records via a break, and modify them if necessary. Log filters
inherit the stream-level hook, but can override or remove the hook as
needed.
The distribution's existing log streams now come with pre-defined
hooks that users can add handlers to. Their name is standardized as
"log_policy" by convention, with additional suffixes when a module
provides multiple streams. The following adds a handler to the Conn
module's default log policy hook:
hook Conn::log_policy(rec: Conn::Info, id: Log::ID, filter: Log::Filter)
{
if ( some_veto_reason(rec) )
break;
}
By default, this handler will get invoked for any log filter
associated with the Conn::LOG stream.
The existing predicates are deprecated for removal in 4.1 but continue
to work.
126 lines
3 KiB
Text
126 lines
3 KiB
Text
##! Implements the core IRC analysis support. The logging model is to log
|
|
##! IRC commands along with the associated response and some additional
|
|
##! metadata about the connection if it's available.
|
|
|
|
module IRC;
|
|
|
|
export {
|
|
|
|
redef enum Log::ID += { LOG };
|
|
|
|
global log_policy: Log::PolicyHook;
|
|
|
|
type Info: record {
|
|
## Timestamp when the command was seen.
|
|
ts: time &log;
|
|
## Unique ID for the connection.
|
|
uid: string &log;
|
|
## The connection's 4-tuple of endpoint addresses/ports.
|
|
id: conn_id &log;
|
|
## Nickname given for the connection.
|
|
nick: string &log &optional;
|
|
## Username given for the connection.
|
|
user: string &log &optional;
|
|
|
|
## Command given by the client.
|
|
command: string &log &optional;
|
|
## Value for the command given by the client.
|
|
value: string &log &optional;
|
|
## Any additional data for the command.
|
|
addl: string &log &optional;
|
|
};
|
|
|
|
## Event that can be handled to access the IRC record as it is sent on
|
|
## to the logging framework.
|
|
global irc_log: event(rec: Info);
|
|
}
|
|
|
|
redef record connection += {
|
|
## IRC session information.
|
|
irc: Info &optional;
|
|
};
|
|
|
|
const ports = { 6666/tcp, 6667/tcp, 6668/tcp, 6669/tcp };
|
|
redef likely_server_ports += { ports };
|
|
|
|
event zeek_init() &priority=5
|
|
{
|
|
Log::create_stream(IRC::LOG, [$columns=Info, $ev=irc_log, $path="irc", $policy=log_policy]);
|
|
Analyzer::register_for_ports(Analyzer::ANALYZER_IRC, ports);
|
|
}
|
|
|
|
function new_session(c: connection): Info
|
|
{
|
|
local info: Info;
|
|
info$ts = network_time();
|
|
info$uid = c$uid;
|
|
info$id = c$id;
|
|
return info;
|
|
}
|
|
|
|
function set_session(c: connection)
|
|
{
|
|
if ( ! c?$irc )
|
|
c$irc = new_session(c);
|
|
|
|
c$irc$ts=network_time();
|
|
}
|
|
|
|
event irc_nick_message(c: connection, is_orig: bool, who: string, newnick: string) &priority=5
|
|
{
|
|
set_session(c);
|
|
if ( is_orig )
|
|
{
|
|
c$irc$command = "NICK";
|
|
c$irc$value = newnick;
|
|
}
|
|
}
|
|
|
|
event irc_nick_message(c: connection, is_orig: bool, who: string, newnick: string) &priority=-5
|
|
{
|
|
if ( is_orig )
|
|
{
|
|
Log::write(IRC::LOG, c$irc);
|
|
c$irc$nick = newnick;
|
|
}
|
|
}
|
|
|
|
event irc_user_message(c: connection, is_orig: bool, user: string, host: string, server: string, real_name: string) &priority=5
|
|
{
|
|
set_session(c);
|
|
if ( is_orig )
|
|
{
|
|
c$irc$command = "USER";
|
|
c$irc$value = user;
|
|
c$irc$addl=fmt("%s %s %s", host, server, real_name);
|
|
}
|
|
}
|
|
|
|
event irc_user_message(c: connection, is_orig: bool, user: string, host: string, server: string, real_name: string) &priority=-5
|
|
{
|
|
if ( is_orig )
|
|
{
|
|
Log::write(IRC::LOG, c$irc);
|
|
c$irc$user = user;
|
|
}
|
|
}
|
|
|
|
event irc_join_message(c: connection, is_orig: bool, info_list: irc_join_list) &priority=5
|
|
{
|
|
set_session(c);
|
|
if ( is_orig )
|
|
c$irc$command = "JOIN";
|
|
}
|
|
|
|
event irc_join_message(c: connection, is_orig: bool, info_list: irc_join_list) &priority=-5
|
|
{
|
|
if ( is_orig )
|
|
{
|
|
for ( l in info_list )
|
|
{
|
|
c$irc$value = l$channel;
|
|
c$irc$addl = (l$password != "" ? fmt(" with channel key: '%s'", l$password) : "");
|
|
Log::write(IRC::LOG, c$irc);
|
|
}
|
|
}
|
|
}
|