mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 14:48:21 +00:00
597a4d6704
- policy/ renamed to scripts/ - By default BROPATH now contains: - scripts/ - scripts/policy - scripts/site - *Nearly* all tests pass. - All of scripts/base/ is loaded by main.cc - Can be disabled by setting $BRO_NO_BASE_SCRIPTS - Scripts in scripts/base/ don't use relative path loading to ease use of BRO_NO_BASE_SCRIPTS (to copy and paste that script). - The scripts in scripts/base/protocols/ only (or soon will only) do logging and state building. - The scripts in scripts/base/frameworks/ add functionality without causing any additional overhead. - All "detection" activity happens through scripts in scripts/policy/. - Communications framework modified temporarily to need an environment variable to actually enable (ENABLE_COMMUNICATION=1) - This is so the communications framework can be loaded as part of the base without causing trouble when it's not needed. - This will be removed once a resolution to ticket #540 is reached.
37 lines
1.2 KiB
Text
37 lines
1.2 KiB
Text
##! Script for detecting strange activity within DNS.
|
|
##!
|
|
##! Notices raised:
|
|
##!
|
|
##! * :bro:enum:`DNS::External_Name`
|
|
##!
|
|
##! A remote host resolves to a local host, but the name is not considered
|
|
##! to be within a local zone. :bro:id:`local_zones` variable **must**
|
|
##! be set appropriately for this detection.
|
|
|
|
module DNS;
|
|
|
|
export {
|
|
redef enum Notice::Type += {
|
|
## Raised when a non-local name is found to be pointing at a local host.
|
|
## This only works appropriately when all of your authoritative DNS
|
|
## servers are located in your :bro:id:`Site::local_nets`.
|
|
External_Name,
|
|
};
|
|
}
|
|
|
|
event dns_A_reply(c: connection, msg: dns_msg, ans: dns_answer, a: addr) &priority=-3
|
|
{
|
|
if ( |Site::local_zones| == 0 )
|
|
return;
|
|
|
|
# Check for responses from remote hosts that point at local hosts
|
|
# but the name is not considered to be within a "local" zone.
|
|
if ( Site::is_local_addr(a) && # referring to a local host
|
|
!Site::is_local_addr(c$id$resp_h) && # response from an external nameserver
|
|
!Site::is_local_name(ans$query) ) # name isn't in a local zone.
|
|
{
|
|
NOTICE([$note=External_Name,
|
|
$msg=fmt("%s is pointing to a local host - %s.", ans$query, a),
|
|
$conn=c]);
|
|
}
|
|
}
|