mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 06:38:20 +00:00
46 lines
1.9 KiB
CMake
46 lines
1.9 KiB
CMake
include(TestBigEndian)
|
|
test_big_endian(HOST_BIGENDIAN)
|
|
|
|
include(CheckTypeSize)
|
|
check_type_size("unsigned int" SIZEOF_UNSIGNED_INT)
|
|
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/binpac.h.in ${CMAKE_CURRENT_BINARY_DIR}/binpac.h)
|
|
|
|
include_directories(${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
|
|
set(binpac_headers ${CMAKE_CURRENT_BINARY_DIR}/binpac.h binpac_analyzer.h binpac_buffer.h
|
|
binpac_bytestring.h binpac_exception.h binpac_regex.h)
|
|
|
|
set(binpac_lib_SRCS binpac_buffer.cc binpac_bytestring.cc binpac_regex.cc)
|
|
|
|
if (BUILD_STATIC_BINPAC)
|
|
add_library(binpac_static STATIC)
|
|
target_sources(binpac_static PRIVATE ${binpac_lib_SRCS})
|
|
set_target_properties(binpac_static PROPERTIES OUTPUT_NAME binpac)
|
|
install(TARGETS binpac_static DESTINATION ${CMAKE_INSTALL_LIBDIR})
|
|
if (MSVC)
|
|
target_compile_options(binpac_static PRIVATE "/J")
|
|
endif ()
|
|
set(BinPAC_LIBRARY binpac_static CACHE STRING "BinPAC library" FORCE)
|
|
zeek_target_add_linters(binpac_static)
|
|
else ()
|
|
add_library(binpac_lib SHARED)
|
|
target_sources(binpac_lib PRIVATE ${binpac_lib_SRCS})
|
|
target_sources(binpac_lib INTERFACE ${binpac_headers})
|
|
set_target_properties(binpac_lib PROPERTIES MACOSX_RPATH true OUTPUT_NAME binpac)
|
|
if (MSVC)
|
|
target_compile_options(binpac_lib PRIVATE "/J")
|
|
endif ()
|
|
install(TARGETS binpac_lib DESTINATION ${CMAKE_INSTALL_LIBDIR})
|
|
set(BinPAC_LIBRARY binpac_lib CACHE STRING "BinPAC library" FORCE)
|
|
zeek_target_add_linters(binpac_lib)
|
|
endif ()
|
|
|
|
if (ZEEK_ROOT_DIR)
|
|
# Installed in binpac subdir just for organization purposes.
|
|
install(FILES ${binpac_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/binpac)
|
|
else ()
|
|
install(FILES ${binpac_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
|
|
endif ()
|
|
|
|
set(BinPAC_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}
|
|
CACHE STRING "BinPAC header directories" FORCE)
|