mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 14:48:21 +00:00
b477d2b02d
- New, expanded API. - Calculations moved into plugins. - Scripts using measurement framework ported. - Updated the script-land queue implementation to make it more generic. -
52 lines
No EOL
1.3 KiB
Text
52 lines
No EOL
1.3 KiB
Text
|
|
module Measurement;
|
|
|
|
export {
|
|
redef enum Calculation += {
|
|
## Calculate the number of unique values.
|
|
UNIQUE
|
|
};
|
|
|
|
redef record ResultVal += {
|
|
## If cardinality is being tracked, the number of unique
|
|
## items is tracked here.
|
|
unique: count &default=0;
|
|
};
|
|
}
|
|
|
|
redef record ResultVal += {
|
|
# Internal use only. This is not meant to be publically available
|
|
# because we don't want to trust that we can inspect the values
|
|
# since we will like move to a probalistic data structure in the future.
|
|
# TODO: in the future this will optionally be a hyperloglog structure
|
|
unique_vals: set[DataPoint] &optional;
|
|
};
|
|
|
|
hook add_to_reducer_hook(r: Reducer, val: double, data: DataPoint, rv: ResultVal)
|
|
{
|
|
if ( UNIQUE in r$apply )
|
|
{
|
|
if ( ! rv?$unique_vals )
|
|
rv$unique_vals=set();
|
|
add rv$unique_vals[data];
|
|
rv$unique = |rv$unique_vals|;
|
|
}
|
|
}
|
|
|
|
hook compose_resultvals_hook(result: ResultVal, rv1: ResultVal, rv2: ResultVal)
|
|
{
|
|
if ( rv1?$unique_vals || rv2?$unique_vals )
|
|
{
|
|
if ( rv1?$unique_vals )
|
|
result$unique_vals = rv1$unique_vals;
|
|
|
|
if ( rv2?$unique_vals )
|
|
if ( ! result?$unique_vals )
|
|
result$unique_vals = rv2$unique_vals;
|
|
else
|
|
for ( val2 in rv2$unique_vals )
|
|
add result$unique_vals[val2];
|
|
|
|
result$unique = |result$unique_vals|;
|
|
}
|
|
} |