mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 06:38:20 +00:00
bec965b66f
- On-demand access to sumstats results through "return from" functions named SumStats::request and Sumstats::request_key. Both functions are tested in standalone and clustered modes. - $name field has returned to SumStats which simplifies cluster code and makes the on-demand access stuff possible. - Clustered results can only be collected for 1 minute from their time of creation now instead of time of last read. - Thresholds use doubles instead of counts everywhere now. - Calculation dependency resolution occurs at start up time now instead of doing it at observation time which provide a minor cpu performance improvement. A new plugin registration mechanism was created to support this change. - AppStats now has a minimal doc string and is broken into hook-based plugins. - AppStats and traceroute detection added to local.bro
53 lines
1.3 KiB
Text
53 lines
1.3 KiB
Text
@load ../main
|
|
|
|
module SumStats;
|
|
|
|
export {
|
|
redef enum Calculation += {
|
|
## Calculate the number of unique values.
|
|
UNIQUE
|
|
};
|
|
|
|
redef record ResultVal += {
|
|
## If cardinality is being tracked, the number of unique
|
|
## items is tracked here.
|
|
unique: count &default=0;
|
|
};
|
|
}
|
|
|
|
redef record ResultVal += {
|
|
# Internal use only. This is not meant to be publically available
|
|
# because we don't want to trust that we can inspect the values
|
|
# since we will like move to a probalistic data structure in the future.
|
|
# TODO: in the future this will optionally be a hyperloglog structure
|
|
unique_vals: set[Observation] &optional;
|
|
};
|
|
|
|
hook register_observe_plugins()
|
|
{
|
|
register_observe_plugin(UNIQUE, function(r: Reducer, val: double, obs: Observation, rv: ResultVal)
|
|
{
|
|
if ( ! rv?$unique_vals )
|
|
rv$unique_vals=set();
|
|
add rv$unique_vals[obs];
|
|
rv$unique = |rv$unique_vals|;
|
|
});
|
|
}
|
|
|
|
hook compose_resultvals_hook(result: ResultVal, rv1: ResultVal, rv2: ResultVal)
|
|
{
|
|
if ( rv1?$unique_vals || rv2?$unique_vals )
|
|
{
|
|
if ( rv1?$unique_vals )
|
|
result$unique_vals = rv1$unique_vals;
|
|
|
|
if ( rv2?$unique_vals )
|
|
if ( ! result?$unique_vals )
|
|
result$unique_vals = rv2$unique_vals;
|
|
else
|
|
for ( val2 in rv2$unique_vals )
|
|
add result$unique_vals[val2];
|
|
|
|
result$unique = |result$unique_vals|;
|
|
}
|
|
}
|