mirror of
https://github.com/zeek/zeek.git
synced 2025-10-02 22:58:20 +00:00
597a4d6704
- policy/ renamed to scripts/ - By default BROPATH now contains: - scripts/ - scripts/policy - scripts/site - *Nearly* all tests pass. - All of scripts/base/ is loaded by main.cc - Can be disabled by setting $BRO_NO_BASE_SCRIPTS - Scripts in scripts/base/ don't use relative path loading to ease use of BRO_NO_BASE_SCRIPTS (to copy and paste that script). - The scripts in scripts/base/protocols/ only (or soon will only) do logging and state building. - The scripts in scripts/base/frameworks/ add functionality without causing any additional overhead. - All "detection" activity happens through scripts in scripts/policy/. - Communications framework modified temporarily to need an environment variable to actually enable (ENABLE_COMMUNICATION=1) - This is so the communications framework can be loaded as part of the base without causing trouble when it's not needed. - This will be removed once a resolution to ticket #540 is reached.
52 lines
1.8 KiB
Text
52 lines
1.8 KiB
Text
##! Functions for creating and working with patterns.
|
|
|
|
## Given a pattern as a string with two tildes (~~) contained in it, it will
|
|
## return a pattern with string set's elements OR'd together where the
|
|
## double-tilde was given (this function only works at or before init time).
|
|
## ss: a set of strings to OR together
|
|
## pat: the pattern containing a "~~" in it. If a literal backslash is
|
|
## included, it needs to be escaped with another backslash due to Bro's
|
|
## string parsing reducing it to a single backslash upon rendering.
|
|
## Returns: the input pattern with "~~" replaced by OR'd elements of input set
|
|
function set_to_regex(ss: set[string], pat: string): pattern
|
|
{
|
|
local i: count = 0;
|
|
local return_pat = "";
|
|
for ( s in ss )
|
|
{
|
|
local tmp_pattern = convert_for_pattern(s);
|
|
return_pat = ( i == 0 ) ?
|
|
tmp_pattern : cat(tmp_pattern, "|", return_pat);
|
|
++i;
|
|
}
|
|
return string_to_pattern(sub(pat, /~~/, return_pat), F);
|
|
}
|
|
|
|
type PatternMatchResult: record {
|
|
## T if a match was found, F otherwise.
|
|
matched: bool;
|
|
## Portion of string that first matched.
|
|
str: string;
|
|
## 1-based offset where match starts.
|
|
off: count;
|
|
};
|
|
|
|
## Matches the given pattern against the given string, returning
|
|
## a :bro:type:`PatternMatchResult` record.
|
|
## For example: ``match_pattern("foobar", /o*[a-k]/)`` returns
|
|
## ``[matched=T, str=f, off=1]``, because the *first* match is for
|
|
## zero o's followed by an [a-k], but ``match_pattern("foobar", /o+[a-k]/)``
|
|
## returns ``[matched=T, str=oob, off=2]``
|
|
## s: a string to match against
|
|
## p: a pattern to match
|
|
## Returns: a record indicating the match status
|
|
function match_pattern(s: string, p: pattern): PatternMatchResult
|
|
{
|
|
local a = split_n(s, p, T, 1);
|
|
|
|
if ( |a| == 1 )
|
|
# no match
|
|
return [$matched = F, $str = "", $off = 0];
|
|
else
|
|
return [$matched = T, $str = a[2], $off = |a[1]| + 1];
|
|
}
|